1. 指标公式如何改写成选股条件公式
【一品抄底】，是个副图指标，既有线性输出信号，也有买点提示信号，输出类别众多，就不是一个单独的选股指标。如何修改、拆分出自己需要的【底部】选股信号，成为一个单独的选股指标呢？如果还需要将【深坑】的信号，也单独设置为选股指标，又该如何修改呢？在此先当做一个问题吧，继续看了后面（二）、（三）小节的引路，相信你自己来就行了！
{一品抄底----创幻论坛一品茶缘编写，通用副图指标}
TYP := (HIGH + LOW + CLOSE)/3;
CCI:=(TYP-MA(TYP,14))/(0.015*AVEDEV(TYP,14));
A:=REF(C,1);
RSI:=SMA(MAX(C-A,0),6,1)/SMA(ABS(C-A),6,1)*100;
A1:=(C/MA(C,5)-1)*100<-10;
A2:=(C/MA(C,13)-1)*100<-10;
A3:=(C/MA(C,34)-1)*100<-15;
A4:=RSI<18;
A5:=CCI<-120;
A6:=COUNT(ABS(C/REF(C,1)-1)*100>=6,30)>=1;
底部:A1 AND A2 AND A3 AND A4 AND A5 AND A6,COLOR00FFFF,LINETHICK2;
CDSJ:=BARSLAST(底部);
ZF:=(C/REF(C,1)-1)*100;
深坑:IF(BETWEEN(CDSJ,0,5) AND L<=REF(C,CDSJ) AND ZF<=-5,-0.5,0),COLORFF0000,LINETHICK2;
机会:IF(CDSJ<=7 AND L<=REF(C,CDSJ),0.5,0),COLOR00FF00;
寻找选股信号的来源
所谓选股信号，多数都是属于将已有的指标公式中具有买点类的信号特征“剥离”出来。那么，在指标中该保留哪些有用的源码，删除哪些无关的源码呢？寻找选股信号的来源，就是最主要的过程。
寻找选股信号来源的方法，一般都是遵循从后往前寻找的原则。
具体步骤是：先找到发出指标信号的那行代码，然后查看该行代码中的所有条件，需要用到上面哪些源码，再从后往前一一对应寻找出来；而其他无关的条件、修饰符号源码，均可删除。
举例3：（本例子参考大庆老杨先生帖子，略有改动）
{股市马经----副图指标，源码来自网络}
A1:3*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1)-2*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1);
黑马线:EMA(A1,5),LINETHICK2,COLOR6600FF;
A2:=(黑马线-REF(黑马线,1))/REF(黑马线,1)*100;
A3:=EMA(C,5);
A4:=((C-LLV(L,21))/(HHV(H,21)-LLV(L,21)))*100;
趋势线:(MA(3*SMA(A4,6,1)-2*SMA(SMA(A4,5,1),5,1),2)),LINETHICK2,coloryellow;
A5:=(HHV(H,60)-C)/(HHV(H,60)-LLV(L,60))*100;
DRAWTEXT(FILTER(REF(黑马线,1)>90 AND A2<0,7),黑马线,'跑'),COLOR00FF00;
DRAWTEXT(CROSS(A1,黑马线)AND 黑马线<A5,黑马线,'黑马');
DRAWTEXT(CROSS(黑马线,A5)AND 趋势线<80,黑马线,'追涨');
DRAWTEXT(CROSS(趋势线,0)AND 黑马线<40,5,'大黑马');
底部:(A2<-10 AND A2>REF(A2,1))*25,colorred;
DRAWICON(底部 AND A3>REF(A3,1),25,4);
机会来临:REF(IF((MA(C,5)-C)/C>0.04 AND (MA(C,10)-MA(C,5))/MA(C,5)>0.04,30,0),1),COLORF00FF0;
大势已去:IF(CROSS(黑马线,A1)AND 黑马线>70 AND 趋势线>80,90,100),COLORFF0000;
公式中涉及“买”的信号有黑马、追涨、大黑马、底部和机会来临五个明显的，另外还有一个画图标信号。
假如我们提取其中的【机会来临】，仔细分析后，就是一句话：
机会来临:REF(IF((MA(C,5)-C)/C>0.04 AND (MA(C,10)-MA(C,5))/MA(C,5)>0.04,30,0),1);
这个可看作简单提取。
如果提取【大黑马】的话，从后向前推，涉及趋势线和黑马线两个定义，这部分都有用：
A1:3*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1)-2*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1);
黑马线:EMA(A1,5),LINETHICK2,COLOR6600FF;
A4:=((C-LLV(L,21))/(HHV(H,21)-LLV(L,21)))*100;
趋势线:(MA(3*SMA(A4,6,1)-2*SMA(SMA(A4,5,1),5,1),2)),LINETHICK2,coloryellow;
DRAWTEXT(CROSS(趋势线,0) AND 黑马线<40,5,'大黑马');
（三）修改选股指标的方法
根据以上选股公式的特征，结合寻找选股信号来源的方法，自己动手修改选股信号，应该就没有太大的难度了！
举例4：继续承接上面（二）的例子。
修改步骤：
①先将线性输出的A1、黑马线、A4、趋势线均限制输出，方法很简单，就是在他们的冒号后面直接加上等号=；
②再删去修饰符LINETHICK2,COLOR6600FF：
③将本来是文字输出的“黑马线”修改成信号输出；先将“黑马线”三个字移动到最前面，并加上冒号：；然后保留符合黑马线的限制条件CROSS(趋势线,0) AND 黑马线<40；同时删除其余无关的代码，包括文字输出函数DRAWTEXT、位置、括号（）等。
修改成选股指标后的源码如下：
A1:=3*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1)-2*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1);
黑马线:=EMA(A1,5);
A4:=((C-LLV(L,21))/(HHV(H,21)-LLV(L,21)))*100;
趋势线:=(MA(3*SMA(A4,6,1)-2*SMA(SMA(A4,5,1),5,1),2));
大黑马:CROSS(趋势线,0) AND 黑马线<40;
举例5：
下面附图指标【大三浪】中，如何选出出现“买”字提示信号的选股指标？
{大三浪----创幻论坛一品茶缘编写，通用副图指标}
{大三浪指标使用说明:
均线粘合且多头,长期未涨庄吸筹;
目标锁定先跟踪,出击买入等丰收!}
{N:30,120,65;}
MA5:=MA(CLOSE,5);
MA21:=MA(CLOSE,21);
MA65:=MA(CLOSE,N);
多头:=COUNT(MA21>MA65,10)=10;
GX:=MAX(MA5,MAX(MA21,MA65));
DX:=MIN(MA5,MIN(MA21,MA65));
粘合:=ABS(GX/DX-1)*100<=15;
多头粘合:IF(多头 AND 粘合,1,0),COLORFF00FF,POINTDOT,LINETHICK0;
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
庄股:COUNT(MACD<0,10)=10,COLORFFFF00,POINTDOT,LINETHICK0;
目标:IF(多头 AND 粘合 AND 庄股,5,0),COLORFFFFFF,LINETHICK2;
跟踪:IF(目标,BARSLAST(CROSS(目标,0))+1,0),COLOR00FF00,POINTDOT,LINETHICK2;
出击:IF(CROSS(0.1,目标) AND CROSS(MACD,0),8,0),COLOR00FFFF,LINETHICK2;
MJSJ:=BARSLAST(出击>0);
涨幅:IF(MJSJ<=120,(C/REF(C,MJSJ)-1)*100,0),COLOR0000FF,POINTDOT,LINETHICK0;
日涨:IF(MJSJ<=120,涨幅/MJSJ,0),COLORFFFFFF,POINTDOT,LINETHICK0;
TPX:=MIN(MA65*1.15,MA21*1.13);
突破:IF(CROSS(C,TPX) AND 粘合 AND MA65>REF(MA65,1),10,0),COLOR0000FF,LINETHICK2;
{以下设置副图显示方式}
STICKLINE(多头粘合,0,1,8,0),COLORFF00FF;
STICKLINE(庄股,0,MACD*10,8,0),COLORFFFF00;
DRAWTEXT(出击=8,10,'★买'),COLOR00FFFF;
VERTLINE(CROSS(涨幅,20) AND COUNT(CROSS(涨幅,20),MJSJ)=1,2),COLOR0000FF; 根据选股指标的步骤，一步一步来：
①首先找到出现“★买”提示的一行代码，发现她其实就是“出击”的信号；
②从后往前，找到“出击”信号的条件，发现他与“目标”、MACD有关；
再次往前寻找，又发现“目标”信号的条件，与“多头”、“粘合”、“庄股”三个条件有关，由此，保留相关条件代码，其余删除，如下：
{N:30,120,65;}
MA5:=MA(CLOSE,5);
MA21:=MA(CLOSE,21);
MA65:=MA(CLOSE,N);
多头:=COUNT(MA21>MA65,10)=10;
GX:=MAX(MA5,MAX(MA21,MA65));
DX:=MIN(MA5,MIN(MA21,MA65));
粘合:=ABS(GX/DX-1)*100<=15;
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
庄股:COUNT(MACD<0,10)=10,COLORFFFF00,POINTDOT,LINETHICK0;
目标:IF(多头 AND 粘合 AND 庄股,5,0),COLORFFFFFF,LINETHICK2;
出击:IF(CROSS(0.1,目标) AND CROSS(MACD,0),8,0),COLOR00FFFF,LINETHICK2;
③限制输出数量，只保留“出击”信号的输出，其他的输出信号均加上等号=加以限制输出；
④删除多余的修饰符号，如：COLORFFFF00,POINTDOT,LINETHICK0等。
⑤IF格式也可简化，只保留需要的条件，输出信号自动为1。“出击”两字也可修改为“买”。
修改完最后保留的源码如下：
{大三浪----选股指标}
{N:30,120,65;}
MA5:=MA(CLOSE,5);
MA21:=MA(CLOSE,21);
MA65:=MA(CLOSE,N);
多头:=COUNT(MA21>MA65,10)=10;
GX:=MAX(MA5,MAX(MA21,MA65));
DX:=MIN(MA5,MIN(MA21,MA65));
粘合:=ABS(GX/DX-1)*100<=15;
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
庄股:=COUNT(MACD<0,10)=10;
目标:=IF(多头 AND 粘合 AND 庄股,5,0);
买:CROSS(0.1,目标) AND CROSS(MACD,0); 导入选股指标的途径
①修改完后的选股指标源码，想做成选股指标，并非放在指标系统之下的【技术指标】分类，一般是放入【条件选股】分类；便于设置预警、自动选股。
②还可将选股指标加入交易系统中，但需要注意的是：输出信号必须为英文单词的买入ENTERLONG、卖出EXITLONG信号。在应用时，飞狐软件输入该交易系统指标名称，即可在主图自动显示买卖信号的提示。
源码如下：
ENTERLONG:CROSS(MA(C,3),MA(C,8));----表示输出多头买入信号。
EXITLONG:CROSS(MA(C,8),MA(C,3));----表示输出空头卖出信号。
2. 比较好的买卖点提示的股票指标公式
通达信软件里面有上千个指标公式，提供一个本人在用的买卖点把握以及解决持股问题的简洁公式。
操盘手指标公式源码：
A:=AMOUNT/V/100;
VARA:=EMA((((A-EMA(A,13))/EMA(A,13))*(0-100)),5);
操盘线:=EMA(((VARA/10)+EMA(A,10)),3);
行情线:=EMA(A,3);
重心:=(C+0.618*REF(C,1)+0.382*REF(C,2)+0.236*REF(C,3)+0.146*REF(C,4))/2.382;
趋势线:EMA(((SLOPE(C,22)*20)+C),55),COLORYELLOW,LINETHICK2;
红升:IF(重心>=趋势线,趋势线,DRAWNULL),COLORRED,LINETHICK2;
蓝降:IF(重心<趋势线,趋势线,DRAWNULL),COLORBLUE,LINETHICK2;
STICKLINE(行情线<操盘线,H,L,0,1),COLORGREEN;
STICKLINE(行情线<操盘线,C,O,2,1),COLORGREEN;
STICKLINE(行情线>=操盘线,H,L,0,1),COLORRED;
STICKLINE(行情线>=操盘线,C,O,2,1),COLORRED;
{顶底信号}
买线:=EMA(C,5);
卖线:=EMA(C,13);
BU:=CROSS(买线,卖线);
SEL:=CROSS(卖线,买线);
DRAWICON(BU,LOW*0.971,7);
DRAWICON(SEL,HIGH*1.011,8);
{涨跌停显示}
涨停:=IF((C-REF(C,1))*100/REF(C,1)>=(10-0.01*100/REF(C,1)),1,0);
STICKLINE(涨停,O,C,2,0),COLORRED;
跌停:=IF((REF(C,1)-C)*100/REF(C,1)>=(10-0.01*100/REF(C,1)),1,0);
STICKLINE(跌停,O,C,2,1),COLORGREEN;
AA1:=AMOUNT/VOL;
BB1:=L<AA1*0.9;
CC1:=(C-REF(C,1))/REF(C,1)*100>1.2;
DD1:=L<MA(C,5)*0.921;
EE1:=VOL<MA(V,5)*1.5;
FF1:=BB1 AND CC1 AND DD1 AND EE1;
DRAWTEXT(FF1,L*0.99,'B1'),COLORRED;
加分可以再给你几个，哈哈！~
友情提示：指标不在多，而在精，看你能不能把它用好。
3. 想要一个通达信的分时线买卖点公式指标！谢谢！
分时交易
A1:=(VOL/CLOSE)/2;
A2:=SUM(IF(A1>100 AND CLOSE>ref(CLOSE,1),A1,0),0);
A3:=SUM(IF(A1>100 AND CLOSE<ref(CLOSE,1),A1,0),0);
A4:=SUM(IF(A1<100 AND CLOSE>ref(CLOSE,1),A1,0),0);
A5:=SUM(IF(A1<100 AND CLOSE<ref(CLOSE,1),A1,0),0);
机构买盘:A2,LINETHICK3, COLORRED;
机构卖盘:A3,LINETHICK3,COLORGREEN;
散户买盘:A4,COLORMAGENTA;
散户卖盘:A5,COLORWHITE;
机构买:CROSS(机构买盘,机构卖盘);
DRAWTEXT(机构买,机构买盘,'★'),COLORRED;
机构卖:CROSS(机构卖盘,机构买盘);
DRAWTEXT(机构卖,机构卖盘,'☆'),COLORWHITE;
{本文来源：小牛股票公式网www_028588_com }
分时奥秘
多 :( 1*(EMA(c,21) - EMA(c,453)))*10 ,precis1, colorwhite;
空 :(eMA(多,55))*1,precis1,coloryelLOW;
界:(2),precis1,colorcyan;
轴:(0),precis1,colorblue;
tp:=cross(多,界);
tp1:=cross(多,空) AND 空>=0;
DRAWTEXT(TP ,5,'追'),coloryelLOW,LINETHICK0;
DRAWTEXT(TP1 ,10,'买'),COLORgreen,LINETHICK1;
分时涨停
交易:=((SUM(if(time>93000,transactvol(1,0),0),0)-SUM(if(time>93000,transactvol(2,0),0),0))/(SUM(if(time>93000,transactvol(1,0),0),0)+SUM(if(time>93000,transactvol(2,0),0),0)));
k8:=barslast(SUM(if(time>93000,transactnum(1,0)-transactnum(2,0),0),0)>llv(SUM(if(time>93000,transactnum(1,0)-transactnum(2,0),0),0),0))<3 and barslast(SUM(if(time>93000,ORDERNUM(2,0)-ORDERNUM(1,0),0),0)>llv(SUM(if(time>93000,ORDERNUM(2,0)-ORDERNUM(1,0),0),0),0))<3;
k11:=barslast(SUM(if(time>93000,transactnum(1,0)-transactnum(2,0),0),0)>0)<3 and barslast(SUM(if(time>93000,ORDERNUM(2,0)-ORDERNUM(1,0),0),0)>0)<3;
k14:=barslast(SUM(if(time>93000,transactnum(1,0)-transactnum(2,0),0),0)>=hhv(SUM(if(time>93000,transactnum(1,0)-transactnum(2,0),0),0),0))<3 and barslast(SUM(if(time>93000,ORDERNUM(2,0)-ORDERNUM(1,0),0),0)>=hhv(SUM(if(time>93000,ORDERNUM(2,0)-ORDERNUM(1,0),0),0),0))<3;
k17:=high/dynainfo(4)<(1+3/100);
k22:=barslast(cross(交易,0))<3 and LAST(交易>0)>1;
k23:=barslast(cross(SUM(if(time>93000,transactnum(1,0)-transactnum(2,0),0),0),SUM(if(time>93000,ORDERNUM(2,0)-ORDERNUM(1,0),0),0)))<3;
k25:=k17 and k22 and k23 and k14 and k8 and k11;
主动买:=transactvol(1,0)/10000;
主动卖:=transactvol(2,0)/10000;
主动买量:=SUM(主动买,0);
主动卖量:=SUM(主动卖,0);
主动净量:=主动买量-主动卖量;
分时主动率:(主动买量-主动卖量)/(主动买量+主动卖量),COLORYELLOW;
vertline(k25,0),LINETHICK3,coloryelLOW;
FILLRGN(0,分时主动率,分时主动率>0,rgb(80,0,0),分时主动率<=0,rgb(0,55,55)),LINETHICK2,PRE
4. 我想要一个有买卖点的股票指标公式，随便给个吧
嘿嘿，俺前几天才在网络上找的。送你。。。记住加分给俺，不然做鬼也不放你。。。嘿嘿。公式如下：
K1:EMA(C,5),color003300;
k2:EMA(CLOSE,6),color33FF33;
k3:EMA(CLOSE,9),color33FF33;
k5:EMA(CLOSE,12),color33FF33;
k7:EMA(CLOSE,15),color33FF33;
k10:EMA(CLOSE,18),color33FF33;
k13:EMA(CLOSE,21),color33FF33;
k16:EMA(CLOSE,24),color33FF33;
IF (k2>REF(k2,1),k2,k1),color0000FF;
IF (k3>REF(k3,1),k3,k1),color0000FF;
IF (k5>REF(k5,1),k5,k1),color0000FF;
IF (k7>REF(k7,1),k7,k1),color0000FF;
IF (k10>REF(k10,1),k10,k1),color0000FF;
IF (k13>REF(k13,1),k13,k1),color0000FF;
IF (k16>REF(k16,1),k16,k1),color0000FF;
EMA(C,5),color003300;
5. 跪求一个买卖点公式提示卖点的选股公式，本人万分感谢！
跪求哪位高手帮我解决这个难题，谢谢！另外，这个是通达信原码，之前忘了说。30分奖励。谢谢前面这位朋友的解释和提醒！
6. 你要准确买卖点的股票指标公式吗
没有那么机械死板的公式的，如果有人告诉你有，那是忽悠你的。炒股凭的是感觉，你如果能提前感觉到绝大多数人将要感觉到的感觉，你就能赢钱。