益盟經典指標操盤線源碼

① 有沒有益盟操盤手B點和S點的指標公式，能在通達信上使用

從益盟導出該公式，再導入到通達信軟體試一試就知道了。不可以的話，如果有公式源碼可以按通達信指標編寫方法改寫後使用。

② 求益盟操盤手軟體里的「資金流變」指標源碼 （只要益盟操盤手的本軟體源碼）

該資金流變指標引用函數「LARGEINTRDVOL「和」LARGEOUTTRDVOL」這兩個源碼其他軟體中無，故無法改為其他股軟中能用的源碼。除非你能提供這兩個函數的計算邏輯。

③ 哪位高手知道益盟操盤手分時中的「資金凈流」指標源碼和日K線中的「大單比率」及「資金博弈」源碼

這兩個指標是他們根據第二代數據的分筆成交統計出來的，就算是給你源碼也用不了。同時，其它軟體也不能用，因為每一家軟體公司的數據分拆都不一樣。不過，其實這兩個指標真沒有多大的用處，一般都是他們吹出來的。可能對一些比較有經驗的股民有用，對新手沒有。

④ 那位大仙能找到益盟操盤手中的「短線速利」和「短線跑馬場」指標源代碼

益盟操盤手中的「短線速利」和「短線跑馬場」是特色選股條件，不是指標。選股條件的源碼是無法告知用戶的，添加使用這兩個條件的方法參考下圖。

⑤ 跪求益盟操盤手軟體的指標公式

我是該軟體的正版用戶。
好不好用要看哪方面了，如果你覺得用了軟體就能賺錢，那沒有一款股軟能達到你的要求；如果說功能、客服方面，我覺得蠻好的，有益盟論壇和所在地的工作人員幫忙解答，平時培訓也不少。說到軟體功能，建議自己先到各大論壇下載d版的試試看（我就是這樣），我比較喜歡該軟體的周期共振、板塊指數共振等功能很好用，適合新手和不懂自編公式的股民，有了每個季度的基金持倉數據，就不用再在網上辛苦地找了。

⑥ 求海風1、2、3號和益盟操盤手、操盤手BS線的通達信源碼

1、海風2號
MA5:MA(CLOSE,5),COLORFFFFFF,LINETHICK2;
MA13:MA(CLOSE,13),COLOR00FF00;
MA21:MA(CLOSE,21),COLOR00FFFF,LINETHICK2;
MA34:MA(CLOSE,34),COLORFF00FF;
{MA55:MA(CLOSE,55),COLOR0000FF;}
{MA120:=MA(CLOSE,120),COLORFFFF00;}
天使:=EMA(C,2),COLOR000000;
魔鬼:=EMA(SLOPE(C,21)*20+C,42),COLOR000000;
買:=CROSS(天使,魔鬼);
賣:=CROSS(魔鬼,天使);
DRAWICON(買,L*0.97,1);
DRAWTEXT(買,L*0.95,'進攻'),COLORYELLOW;
DRAWICON(賣,H*1.03,2);
DRAWTEXT(賣,H*1.05,'撤退'),COLORWHITE;
STICKLINE(天使>=魔鬼,LOW,HIGH,0.01,0),COLOR0000DD;
STICKLINE(天使>=魔鬼,CLOSE,OPEN,2,1),COLORRED;
{STICKLINE(天使>=魔鬼,CLOSE,OPEN,3,0),COLOR0000CC;
STICKLINE(天使>=魔鬼,CLOSE,OPEN,2,0),COLOR0000DD;
STICKLINE(天使>=魔鬼,CLOSE,OPEN,1,0),COLOR0000FF;}
{STICKLINE(天使<魔鬼,CLOSE,OPEN,1,0),COLOREEEE00;
STICKLINE(天使<魔鬼,CLOSE,OPEN,2,0),COLORDDDD00;
STICKLINE(天使<魔鬼,CLOSE,OPEN,3,0),COLORCCCC00;}
STICKLINE(天使<魔鬼,LOW,HIGH,0.01,0),COLORFFDD00;
STICKLINE(天使<魔鬼,CLOSE,OPEN,2,0),COLORFFFF00;
STICKLINE(CROSS(天使,魔鬼),OPEN,CLOSE,2.5,0),COLORYELLOW;
STICKLINE(CROSS(魔鬼,天使),OPEN,CLOSE,2.5,0),COLORWHITE;

2、益盟操盤手
VAR1:=(100 - ((90 * (HHV(HIGH,14) - CLOSE)) / (HHV(HIGH,14) - LLV(LOW,14))));
VAR2:=(100 - ((90 * (HHV(HIGH,14) - CLOSE)) / (HHV(HIGH,14) - LLV(LOW,14))));
VAR3:=(100 - MA(((100 * (HHV(HIGH,6) - CLOSE)) / (HHV(HIGH,6) - LLV(LOW,6))),34));
DIR1:=ABS(CLOSE-REF(CLOSE,5));
VIR1:=SUM(ABS(CLOSE-REF(CLOSE,1)),5);
ER1:=DIR1/VIR1;
CS1:=ER1*(0.8-2/8)+2/8;
CQ1:=CS1*CS1;
AMA1:EMA(DMA(CLOSE,CQ1),2) ,COLORWHITE;
DIR2:=ABS(CLOSE-REF(CLOSE,10));
VIR2:=SUM(ABS(CLOSE-REF(CLOSE,1)),10);
ER2:=DIR2/VIR2;
CS2:=ER2*(0.8-2/24)+2/24;
CQ2:=CS2*CS2;
AMA2:EMA(DMA(CLOSE,CQ2),2),COLORGREEN,LINETHICK2;
AMA3:IF(AMA2/REF(AMA2,1)>0.997,AMA2,DRAWNULL),COLORYELLOW,LINETHICK2;
AMA4:IF(AMA2/REF(AMA2,1)>1.001,AMA2,DRAWNULL),COLORRED,LINETHICK2;
STICKLINE((VAR2 < MA(VAR3,6)),CLOSE,OPEN,3,1),COLOR008000;
STICKLINE((VAR2 > MA(VAR3,6)),OPEN,CLOSE,3,1),COLORRED;
STICKLINE(((OPEN > CLOSE) AND (VAR2 > MA(VAR3,6))),(OPEN * 0.998),(CLOSE * 1.0001),2.3,0),COLOR008000;
STICKLINE(((OPEN < CLOSE) AND (VAR2 < MA(VAR3,6))),(CLOSE * 0.998),(OPEN * 1.002),2.3,0),COLORRED;
STICKLINE(((OPEN > CLOSE) AND (VAR2 < MA(VAR3,6))),CLOSE,OPEN,2.3,0),COLOR008000;
DRAWICON(CROSS(VAR2,MA(VAR3,6)),(LOW - (LOW*0.04)),7);
DRAWICON(CROSS(MA(VAR3,6),VAR1),(HIGH+(HIGH*0.03)),8);
PT:=REF(H,1)-REF(L,1);
CDP:=(REF(H,1)+REF(L,1)+REF(C,1)*2)/4;
AH:=CDP+PT;
AL:=CDP-PT;
NH:=CDP*2-REF(L,1);
NL:=CDP*2-REF(H,1);
強:IF(AH>REF(C,1)*1.1,REF(C,1)*1.1,AH)NODRAW;
阻:IF(NH>強,(強-CDP)*0.618+CDP,NH)NODRAW,COLORCYAN;
M:=IF(AL<REF(C,1)/1.1,REF(C,1)/1.1,AL);
撐:IF(NL<M,CDP-(CDP-M)*0.618,NL)NODRAW;
底:IF(AL<REF(C,1)/1.1,REF(C,1)/1.1,AL)NODRAW;

3、操盤手BS線
MA5:MA(C,5),COLORF00FF0;
MA10:MA(C,10),COLORYELLOW;
MA21:MA(C,21),COLORE66878;
MA30:MA(C,30),COLORWHITE;
MA120:MA(C,120),COLOR399C7F,POINTDOT;
MA240:MA(C,240),COLOR000999,POINTDOT;
X1:=(C+L+H)/3;
X2:=EMA(X1,6);
X3:=EMA(X2,5);
DRAWICON(CROSS(X2,X3),L*0.98,7);
DRAWICON(CROSS(X3,X2),H*1.02,8);
STICKLINE(X2>=X3,LOW,HIGH,0.1,1),COLORRED;
STICKLINE(X2>=X3,CLOSE,OPEN,2,2),COLORRED;
STICKLINE(X2>=X3,CLOSE,OPEN,2,8),COLORBROWN;
STICKLINE(X2<X3,LOW,HIGH,0.1,1),COLORGREEN;
STICKLINE(X2<X3,CLOSE,OPEN,2,2),COLORGREEN;
STICKLINE(CROSS(X2,X3),OPEN,CLOSE,2,1),COLORYELLOW;
STICKLINE(CROSS(X3,X2),OPEN,CLOSE,2,1),COLORBLUE;

4、四方力道(主)
V1:=DMA((((HIGH + LOW) + (CLOSE * 2)) / 4.15),0.9);
HY1:=REF(EMA(V1,3),1);
實時線:MA(CLOSE,1),COLOR006400;
神秘線:HY1,COLOR400080;

STICKLINE(C>HY1,LOW,HIGH,1,0),COLORRED;
STICKLINE(C>HY1,CLOSE,OPEN,4.5,0),COLORRED;
STICKLINE(C>HY1,CLOSE,OPEN,4,0),COLORRED;
STICKLINE(C>HY1,CLOSE,OPEN,3,0),COLORRED;
STICKLINE(C>HY1,CLOSE,OPEN,2,0),COLORRED;
STICKLINE(C<=HY1,CLOSE,OPEN,4.5,0),COLORFF4242;
STICKLINE(C<=HY1,CLOSE,OPEN,4,0),COLORFF4242;
STICKLINE(C<=HY1,CLOSE,OPEN,3,0),COLORFF4242;
STICKLINE(C<=HY1,CLOSE,OPEN,2,0),COLORFF4242;
STICKLINE(C<=HY1,LOW,HIGH,1,0),COLORFF4242;

DRAWTEXT(CROSS(CLOSE,HY1),LOW,'買點'),LINETHICK2,COLORYELLOW;
DRAWTEXT(CROSS(HY1,CLOSE),HIGH*1.08,'賣點'),LINETHICK3,COLORWHITE;
APP:=(VOL / (((HIGH - LOW) * 2) - ABS((CLOSE - OPEN))));
ZL:=IF((CLOSE > OPEN),(APP * (HIGH - LOW)),IF((CLOSE < OPEN),(APP * ((HIGH - OPEN) + (CLOSE - LOW))),(VOL / 2)));
SF:=IF((CLOSE > OPEN),(0 - (APP * ((HIGH - CLOSE) + (OPEN - LOW)))),IF((CLOSE < OPEN),(0 - (APP * (HIGH - LOW))),(0 - (VOL / 2))));
庫存能量:=MA((ZL + SF),2);
庫存平均:=MA((ZL + SF),5);
DRAWTEXT(CROSS(庫存能量,庫存平均),L*0.97,''),COLORFF00FF,LINETHICK4;

5、上出下買+三背離
A:=MA(CLOSE,17)+ABS(MA(CLOSE,17)-REF(MA(CLOSE,17),1));
B:=MA(CLOSE,17)+MA(CLOSE,17)-REF(MA(CLOSE,17),1);
分水嶺:IF(MA(CLOSE,17)<B,B,MA(CLOSE,17)),COLORFF00FF,LINETHICK2;
PMA:=分水嶺;
DD:=分水嶺<REF(分水嶺,1);
IF(DD,分水嶺,DRAWNULL),COLOR00FF00,LINETHICK2;
操作線:分水嶺-(EMA(C,3)-分水嶺),COLOR00FFFF,LINETHICK2;
S:=(PMA>操作線);
IF(S,分水嶺,DRAWNULL),COLOR00FF00,POINTDOT,LINETHICK4;
PM:MA(C,5),COLORFFFFCC,LINETHICK2;
IF(PM>REF(PM,1),PM,DRAWNULL),COLORRED,LINETHICK2;
IF(PM=REF(PM,1),PM,DRAWNULL),COLORRED;
IF(PM<REF(PM,1),PM,DRAWNULL),COLORFF9900,LINETHICK2;
DRAWICON(CROSS(分水嶺,操作線),分水嶺-0.1,1);
A1:=BARSLAST(REF(CROSS("MACD.DIF","MACD.DEA"),1));
B1:=REF(C,A1+1)>C AND REF("MACD.DIF",A1+1)<"MACD.DIF" AND CROSS("MACD.DIF","MACD.DEA");
DRAWTEXT(B1>0,L-0.02,'★M'),COLOR00FFFF;
A2:=BARSLAST(REF(CROSS("KDJ.K","KDJ.D"),1));
B2:=REF(C,A2+1)>C AND REF("KDJ.K",A2+1)<"KDJ.K" AND CROSS("KDJ.K","KDJ.D");
DRAWTEXT(B2,L-0.10,'◎K'),COLORFF00FF;
A3:=BARSLAST(REF(CROSS("RSI.RSI1","RSI.RSI2"),1));
B3:=REF(C,A3+1)>C AND REF("RSI.RSI1",A3+1)<"RSI.RSI1" AND CROSS("RSI.RSI1","RSI.RSI2");
DRAWTEXT(B3>0,L-0.18,'◆R'),COLOR0000FF;
C1:=BARSLAST(REF(CROSS("MACD.DEA","MACD.DIF"),1));
D1:=REF(C,C1+1)<C AND REF("MACD.DIF",C1+1)>"MACD.DIF" AND CROSS("MACD.DEA","MACD.DIF");
DRAWTEXT(D1>0,H+0.16,'★M'),COLOR00FF00;
C2:=BARSLAST(REF(CROSS("KDJ.D","KDJ.K"),1));
D2:=REF(C,C2+1)<C AND REF("KDJ.K",C2+1)>"KDJ.K" AND CROSS("KDJ.D","KDJ.K");
DRAWTEXT(D2>0,H+0.08,'◎K'),COLORFFFFCC;
C3:=BARSLAST(REF(CROSS("RSI.RSI2","RSI.RSI1"),1));
D3:=REF(C,C3+1)<C AND REF("RSI.RSI1",C3+1)>"RSI.RSI1" AND CROSS("RSI.RSI2","RSI.RSI1");
DRAWTEXT(D3>0,H+0.04,'◆R'),COLORFF9900;

6、變色KDJ
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:SMA(RSV,3,1),COLORWHITE;
D:SMA(K,3,1),COLORYELLOW;
J:3*K-2*D,COLORYELLOW;
IF(K<REF(K,1),K,DRAWNULL),COLORGREEN,LINETHICK1;
IF(D<REF(D,1),D,DRAWNULL),COLORGREEN,LINETHICK1;
IF(J<REF(J,1),J,DRAWNULL),COLORFFFF00,LINETHICK1;
IF(K>REF(K,1),K,DRAWNULL),COLORRED,LINETHICK1;
IF(D>REF(D,1),D,DRAWNULL),COLORRED,LINETHICK1;
IF(J>REF(J,1),J,DRAWNULL),COLORFF00FF,LINETHICK1;

7、變色RSI
N:=3;

N1:=5;N2:=10;N3:=20;N4:=1;M1:=7;M2:=2;

LC :=REF(C,N4);
RSI1:SMA(MAX(C-LC,0),N1,1)/SMA(ABS(C-LC),N1,1)*100,COLORRED,LINETHICK1;
RSI2:SMA(MAX(C-LC,0),N2,1)/SMA(ABS(C-LC),N2,1)*100,COLOR0099FF;
RSI3:SMA(MAX(C-LC,0),N3,1)/SMA(ABS(C-LC),N3,1)*100,COLORYELLOW,LINETHICK1;
IF(RSI1<RSI2,RSI1,DRAWNULL),COLORAA8800,LINETHICK1;
IF(RSI2>RSI1,RSI2,DRAWNULL),COLORAA8800,LINETHICK1;
IF(RSI3>RSI2,RSI3,DRAWNULL)COLORAA8800,LINETHICK1;

TY:=RSI1;{通用曲線值的引入}

AA:=REF(TY,N)=HHV(TY,2*N+1);
BB:=BACKSET(AA,N+1);
CC:=FILTER(BB,N) AND TY=HHV(TY,N+1);
DRAWICON(CC,TY*1.07,10);
AA2:=REF(TY,N)=LLV(TY,2*N+1);
BB2:=BACKSET(AA2,N+1);
CC2:=FILTER(BB2,N) AND TY=LLV(TY,N+1);
DRAWICON(CC2,TY*0.95,11);

GG:=ISLASTBAR AND REF(CC,BARSLAST(CC));
HH:=BACKSET(GG,BARSLAST(CC)+1);
II:=HH>REF(HH,1);
JJ:=REF(BARSLAST(CC),1);
KK:=BACKSET(II,JJ+2);
LL:=KK>REF(KK,1);
DRAWLINE(LL,TY,II,TY,1),COLORRED;
CS:=(REF(TY,BARSLAST(II))-REF(TY,BARSLAST(LL)))/(BARSLAST(LL)-BARSLAST(II));
阻力線:=REF(TY,BARSLAST(II))+BARSLAST(II)*CS;
阻力值:阻力線,LINETHICK0;
DRAWICON(CROSS(TY,阻力線),阻力線*0.99,12);

GG2:=ISLASTBAR AND REF(CC2,BARSLAST(CC2));
HH2:=BACKSET(GG2,BARSLAST(CC2)+1);
II2:=HH2>REF(HH2,1);
JJ2:=REF(BARSLAST(CC2),1);
KK2:=BACKSET(II2,JJ2+2);
LL2:=KK2>REF(KK2,1);
DRAWLINE(LL2,TY,II2,TY,1),COLORGREEN;

8、變色MACD
DIF1:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA1:=EMA(DIF1,9);
MACD1:=2*(DIF1-DEA1),STICK;
MACD2:=EMA(MACD1,3);
STICKLINE(MACD1>MACD2 AND MACD1>0,0,MACD1,1,0),COLORRED;
STICKLINE(MACD1>MACD2 AND MACD1<0,0,MACD1,1,0),COLORGREEN;
STICKLINE(MACD1<MACD2,0,MACD1,1,0),COLORCBCBC0;
STICKLINE(MACD1>=0 OR MACD1<=0,0,0,50,1),COLORWHITE;
DIF:DIF1,COLOR33FF33;
DEA:DEA1,COLORYELLOW;
MACD:MACD1,NODRAW,COLORMAGENTA;
強:IF(DIF1>=DEA1,DIF1,DRAWNULL),COLORRED,LINETHICK2;

⑦ 誰知道益盟操盤手富人按部就班（ABJB）指標源碼啊

現價:C;
頂部: COST(95) ,COLORFFFF33;
賣出: COST(75) ,COLORGREEN;
買入: COST(30) ,COLORRED;
底部: COST(5) ,COLORYELLOW;

⑧ 益盟操盤手公式「ABJB」（按部就班），網上有源碼，但都和操盤手上的不同。誰有真正的按部就班公式源碼

如果能只按照公式就能炒股，現在的有多少億萬富翁啊？！
重要的是知識，不要相信這種東西了，所有的指標都只能是個參考作用，99%的指標都只能使用在股市整體向好的情況下，要想在弱市情況下賺錢，靠得是知識和智慧。