通达信无敌能手升级版主图指标公式

1. 通达信主图指标公式修改：

我看了看，原公式设置是可以互不遮盖的，还需要什么效果？

2. 通达信指标公式编辑，主图，副图

{当股价最高价创六日内新高时，显示K线为黄色，我要添加到均线系统，或者你直接帮我设计出来。5，30，60，120日均线系统}
M5:MA(C,5);
M30:MA(C,30);
M60:MA(C,60);
M120:MA(C,120);
STICKLINE(H>=HHV(H,6),C,O,2,0),COLOR00FFFF;
STICKLINE(H>=HHV(H,6),L,H,0,0),COLOR00FFFF;
====================
{副图成交量，当成交量为创六天新高时，显示成交量为黄色，过去六天新低，为绿色。---"过去六天新低"太难理解，是这样吗？}
VOLUME:VOL,VOLSTICK;
MAVOL1:MA(VOLUME,5);
MAVOL2:MA(VOLUME,10);
STICKLINE(C>O AND V>=HHV(V,6),V,0,2,0),COLOR00FFFF;
STICKLINE(C>O AND V<=LLV(V,6),V,0,2,0),COLOR00FF00;

3. 请老师帮忙编写下图主图指标公式,用在通达信版

通达信专用机构通道主图指标公式
M1:=EMA(C,5);M2:=EMA(C,13);M3:=EMA(C,34);
MC1:=EMA(C,55);MC2:=EMA(C,89);MA4:=EMA(C,144);
判势线:=NEWSAR(1,100),COLORYELLOW,LINETHICK2;
牛熊线:IF(MC1>MAX(MC2,MA4),MC1,IF(MC1<MIN(MC2,MA4),MC2,MA4)),COLORFF00CC,LINETHICK2;
AA:=1;
中轨:EMA(CLOSE,17)*AA,LINETHICK1,COLORFFFFFF;
卖出线:中轨+2*STD(CLOSE,17),LINETHICK1,COLOR0000FF;
买入线:中轨-2*STD(CLOSE,17),LINETHICK1,COLOR00CC00;
清仓线:中轨+3*STD(CLOSE,17),LINETHICK1,COLORFF00FF;
满仓线:中轨-3*STD(CLOSE,17),LINETHICK1,COLOR00AA00;
LOCK:=IF(TIME<1160101,1,0);
VARA:=MA(CLOSE,20);
趋势线:IF(VARA>REF(VARA,2),VARA,IF(VARA<REF(VARA,2),VARA,VARA)),COLOR00FF00;
IF(VARA>REF(VARA,2),VARA,DRAWNULL),LINETHICK2,COLORFF00FF;
IF(VARA=REF(VARA,2),VARA,DRAWNULL),LINETHICK2,COLORFF0000;
IF(VARA<REF(VARA,2),VARA,DRAWNULL),LINETHICK2,COLOR00FF00;
买入:IF(VARA>REF(VARA,2) AND REF(VARA<=REF(VARA,2),1),1,0),NODRAW,COLORAAAAAA;
DRAWICON(CROSS(LOW,满仓线),满仓线*0.96,11);
DRAWICON(CROSS(HIGH,清仓线),HIGH,12);
TY:=CLOSE;
A1:=REF(TY,10)=HHV(TY,2*10+1); B1:=FILTER(A1,10); C1:=BACKSET(B1,10+1); HD:=FILTER(C1,10);
A2:=REF(TY,10)=LLV(TY,2*10+1); B2:=FILTER(A2,10); C2:=BACKSET(B2,10+1); LD:=FILTER(C2,10);
A:=REF(CLOSE,BARSLAST(HD)); B:=REF(CLOSE,BARSLAST(LD));
T1:=BARSLAST(HD)<BARSLAST(LD) AND NOT(HD) ;
T2:=BARSLAST(HD)>BARSLAST(LD) AND NOT(LD);
波峰:IF(T1,A,A),COLORFF00FF,POINTDOT;
STICKLINE(T1,A,A,1.5,0),COLORFF00FF;
波谷:IF(T2,B,B),COLOR80FF00,POINTDOT;
STICKLINE(T2,B,B,1.5,0),COLOR80FF00;
MA1:=MA(C,3);
XG1:=MA1>REF(MA1,1) AND REF(MA1,1)<REF(MA1,2) AND C>MA(C,7);
DRAWTEXT(FILTER(XG1,9),LOW*0.97,'B'),COLORRED,LINETHICK2;
DRAWICON(FILTER(XG1,9),LOW*0.98,1);
VAR2:=SUM(IF(CLOSE>OPEN,VOL,0),30)/SUM(VOL,30)*100;
VAR3:=100-SUM(IF(CLOSE>OPEN,VOL,0),30)/SUM(VOL,30)*100;
多头力量:= VAR2;
空头力量:= VAR3;
RSV:=(CLOSE-LLV(LOW,18))/(HHV(HIGH,18)-LLV(LOW,18))*100;
K:=SMA(RSV,3,1);
D:=SMA(K,3,1);
XG2:=多头力量 > 空头力量 AND 多头力量 - 空头力量>30 AND CROSS(D,K) OR
MA1<REF(MA1,1) AND REF(MA1,1)>REF(MA1,2) AND REF(MA1,2)>REF(MA1,3) AND K>50;
DRAWTEXT(FILTER(XG2,9),H*1.06,'S'),COLORGREEN,LINETHICK2;
DRAWICON(FILTER(XG2,9),H*1.02,2);
{跳空缺口}
LL1:=REF(L,1);
HH1:=REF(H,1);
SQK:=L>HH1;
XQK:=H<LL1;
上跳:IF(SQK=1,L-HH1,DRAWNULL),COLORFF00FF,CROSSDOT,LINETHICK3,NODRAW;
下跳:IF(XQK=1,H-LL1,DRAWNULL),COLORGREEN,CROSSDOT,LINETHICK3,NODRAW;
STICKLINE(SQK,L,HH1,4*1,1),COLORYELLOW;{上跳}
STICKLINE(XQK,H,LL1,4*1,2),COLOR00FF00;{下跳}
DRAWTEXT(SQK,H,'上跳'),COLORYELLOW;
DRAWTEXT(XQK,L,'下跳'),COLOR00FF00;
{补缺口}
K1:=BARSLAST(L>REF(H,1));
K2:=L<REF(H,K1+1) AND COUNT(L<REF(H,K1+1),K1)=1;
STICKLINE(K2,L,O,1,0),COLORFF00FF;{缺口回补};
DRAWTEXT(K2=1,L,'回补'),COLORFF00FF;

4. 通达信将选股公式改为幅图或主图指标

如何将主、副图公式改为选股公式
以下是将主、副图公式改为选股公式的简易方法，求人不如求己。

步骤一.将所有的显示式":",改为不显示式":="
选股条件的基本要求为只能输出1个条件式,故要先将公式中所有的显示式":"改为不显示式":=",
如果原来显示式后面接有线型描述(颜色.对齐..等),也一并删除
例如:
ma1:ma(c,5),colorred;
ma2:ma(c,10),colorgreen,POINTDOT;
.....

先改为
ma1:=ma(c,5);
ma2:=ma(c,10);
.....

步骤二.找出选股条件,并写成选股式引用:
条件的寻找方法,依不同目的,大致可分以下几种:
--------------------------------------------------------------------------------------------
1.'字'选股 如:'买'选股
方法:先找出公式中出现有'字'的地方,该式开头会以DRAW..TEXT开头,
DRAWTEXT DRAWTEXTEX DRAWYITEXT DRAWFLAGTEXT DRAWMOVETEXT
找到后,该函数(条件, ,'字')后面括号内的第1个即为条件,将该条件复制出来并加上分号即可
例如:
{求'5日均>10日均'选股}
ma1:=ma(c,5);
ma2:=ma(c,10);
DRAWTEXT(ma1>ma2,ma1,'5日均>10日均');
[解]
ma1:=ma(c,5);
ma2:=ma(c,10);
ma1>ma2;
--------------------------------------------------------------------------
2.图标选股 如:笑脸选股
方法:
先依不同软件,找出该图标的代号,
再找出公式中出现DRAWICON函数(条件, ,图标代号)的式子,对照图标的代号(括号内的第3个),如果该图标代号为所求代号,
该函数后面括号内的第1个即为条件,将该条件复制出来并加上分号即可
例如:
{求图标1选股}
ma1:=ma(c,5);
ma2:=ma(c,10);
DRAWicon(ma1>ma2,ma1,1);
[解]
ma1:=ma(c,5);
ma2:=ma(c,10);
ma1>ma2;
--------------------------------------------------------------------------------
3.A线上穿(下穿)B线选股 {上穿--金叉,下穿--死叉}
方法:A线上穿B线: cross(A,B);
A线下穿B线: cross(B,A);
例如:
{求ma1上穿ma2选股}
ma1:ma(c,5);
ma2:ma(c,10);
[解]
ma1:=ma(c,5);
ma2:=ma(c,10);
cross(ma1,ma2);

{求ma1下穿ma2选股}
ma1:ma(c,5);
ma2:ma(c,10);
[解]
ma1:=ma(c,5);
ma2:=ma(c,10);
cross(ma2,ma1);

-------------------------------------------------------------------------------------------
4.线A上穿(下穿) 选股
方法:线A上穿: cross(A,ma(A,2)); 或 cross(A,ref(A,1));
线A下穿: cross(ma(A,2),A); 或 cross(ref(A,1),A);
例如:
{求改成ma1上穿}
ma1:ma(c,5);
[解]
ma1:=ma(c,5);
cross(ma1,ma(ma1,2));
或
ma1:=ma(c,5);
cross(ma1,ref(ma1,1));

{求改成ma1下穿}
ma1:ma(c,5);
[解]
ma1:=ma(c,5);
cross(ma(ma1,2),ma1);
或
ma1:=ma(c,5);
cross(ref(ma1,1),ma1);
---------------------------------------------------------------------------------------------
5.第1次出现条件A 选股
方法:先找出条件A,
再利用cross(A,0.5);

例如:
{求改成出现图标1选股}
ma1:=ma(c,5);
ma2:=ma(c,10);
DRAWicon(ma1>ma2,ma1,1);
[解1]
ma1:=ma(c,5);
ma2:=ma(c,10);
A:=ma1>ma2;
cross(A,0.5);
[解2--直接将条件A写入]
ma1:=ma(c,5);
ma2:=ma(c,10);
cross(ma1>ma2,0.5);
-------------------------------------------------------------------------------------------
6.线变色选股 如:黄线变红色选股 (指标线为黄线,再利用函数变红色线)
方法:先依不同软件,找出条件A,
再用cross(A,0.5);

(1)飞狐
条件在PARTLINE(条件A, ),colorred;括号内的第1个即为条件,将该条件复制出来并加上分号即可
例如:
{求黄线变红色选股 飞狐}
ma1:ma(c,5),coloryellow;
PARTLINE(ma1>REF(ma1,1),ma1),colorred;
[解]
ma1:=ma(c,5);
A:=ma1>REF(ma1,1);
cross(A,0.5);

(2)大智慧L2.分析家
条件在PARTLINE( ,条件A,rgb(255,0,0), , ...);
括号内为rgb(255,0,0)的前1个即为条件,将该条件复制出来并加上分号即可
例如:
{求黄线变红色选股 大智慧L2.分析家}
ma1:=ma(c,5);
PARTLINE(ma1,ma1>REF(ma1,1),rgb(255,0,0),1,rgb(255,255,0));
[解]
ma1:=ma(c,5);
A:=ma1>REF(ma1,1);
cross(A,0.5);

(3)通达信
条件在IF(条件A, ,DRAWNULL),colorred;括号内的第1个即为条件,将该条件复制出来并加上分号即可
例如:
{求黄线变红色选股 通达信}
MA1:MA(C,5),COLORYELLOW;
IF(MA1>REF(MA1,1),MA1,DRAWNULL),COLORRED;
[解]
MA1:=MA(C,5);
A:=MA1>REF(MA1,1);
CROSS(MA1>REF(MA1,1),0.5);
--------------------------------------------------------------------------------
7.颜色柱选股
方法:先找出公式中出现有STICKLINE函数的地方,
找到后,核对该函数后面的颜色,是否为所求颜色,
若颜色相同,则括号内的第1个即为条件A,将该条件复制出来并加上分号即可

例如:
{求红色柱选股}
STICKLINE(c>o,h,l,0.8,1),colorred;
[解]
A:c>o;

{求第1次红色柱选股}
STICKLINE(c>o,h,l,0.8,1),colorred;
[解]
A:=c>o;
cross(A,0.5);

步骤三.最后将所有绘图函数及单一输出值(如 0; k; if(,,); )全删除,使公式只剩1个选股式输出即成,
(若有2个以上条件,条件同时成立时,可在条件间用"and"连接;
若有2个以上条件,允许条件不同时成立时,可在条件间用"or"连接)；

5. 通达信最牛最全主图指标公式怎么样

没有最牛的指标，只有最熊的指标

6. 请高手把这个通达信主图公式改成选股指标

第一个

N:=IF(BARSCOUNT(C)>=48,48,BARSCOUNT(C));

AMOV:=VOL*(C+L+H)/3;

MN:=SUM(AMOV,N)/SUM(VOL,N);

XG1:C>MN;

第二个

N1:=IF(BARSCOUNT(C)>=8,8,BARSCOUNT(C));

MN1:=SUM(AMOV,N1)/SUM(VOL,N1);

XG2:C>=MN1 AND REF(C<MN1,1);

你说的收盘价由灰色变为黄色我没看见,短线是由绿色变为黄色,中线是由灰色变为黄色,上面公式第一个是收盘价大于中线,第二个是短线由绿线变为黄色