通達信無敵能手升級版主圖指標公式

1. 通達信主圖指標公式修改：

我看了看，原公式設置是可以互不遮蓋的，還需要什麼效果？

2. 通達信指標公式編輯，主圖，副圖

{當股價最高價創六日內新高時，顯示K線為黃色，我要添加到均線系統，或者你直接幫我設計出來。5，30，60，120日均線系統}
M5:MA(C,5);
M30:MA(C,30);
M60:MA(C,60);
M120:MA(C,120);
STICKLINE(H>=HHV(H,6),C,O,2,0),COLOR00FFFF;
STICKLINE(H>=HHV(H,6),L,H,0,0),COLOR00FFFF;
====================
{副圖成交量，當成交量為創六天新高時，顯示成交量為黃色，過去六天新低，為綠色。---"過去六天新低"太難理解，是這樣嗎？}
VOLUME:VOL,VOLSTICK;
MAVOL1:MA(VOLUME,5);
MAVOL2:MA(VOLUME,10);
STICKLINE(C>O AND V>=HHV(V,6),V,0,2,0),COLOR00FFFF;
STICKLINE(C>O AND V<=LLV(V,6),V,0,2,0),COLOR00FF00;

3. 請老師幫忙編寫下圖主圖指標公式,用在通達信版

通達信專用機構通道主圖指標公式
M1:=EMA(C,5);M2:=EMA(C,13);M3:=EMA(C,34);
MC1:=EMA(C,55);MC2:=EMA(C,89);MA4:=EMA(C,144);
判勢線:=NEWSAR(1,100),COLORYELLOW,LINETHICK2;
牛熊線:IF(MC1>MAX(MC2,MA4),MC1,IF(MC1<MIN(MC2,MA4),MC2,MA4)),COLORFF00CC,LINETHICK2;
AA:=1;
中軌:EMA(CLOSE,17)*AA,LINETHICK1,COLORFFFFFF;
賣出線:中軌+2*STD(CLOSE,17),LINETHICK1,COLOR0000FF;
買入線:中軌-2*STD(CLOSE,17),LINETHICK1,COLOR00CC00;
清倉線:中軌+3*STD(CLOSE,17),LINETHICK1,COLORFF00FF;
滿倉線:中軌-3*STD(CLOSE,17),LINETHICK1,COLOR00AA00;
LOCK:=IF(TIME<1160101,1,0);
VARA:=MA(CLOSE,20);
趨勢線:IF(VARA>REF(VARA,2),VARA,IF(VARA<REF(VARA,2),VARA,VARA)),COLOR00FF00;
IF(VARA>REF(VARA,2),VARA,DRAWNULL),LINETHICK2,COLORFF00FF;
IF(VARA=REF(VARA,2),VARA,DRAWNULL),LINETHICK2,COLORFF0000;
IF(VARA<REF(VARA,2),VARA,DRAWNULL),LINETHICK2,COLOR00FF00;
買入:IF(VARA>REF(VARA,2) AND REF(VARA<=REF(VARA,2),1),1,0),NODRAW,COLORAAAAAA;
DRAWICON(CROSS(LOW,滿倉線),滿倉線*0.96,11);
DRAWICON(CROSS(HIGH,清倉線),HIGH,12);
TY:=CLOSE;
A1:=REF(TY,10)=HHV(TY,2*10+1); B1:=FILTER(A1,10); C1:=BACKSET(B1,10+1); HD:=FILTER(C1,10);
A2:=REF(TY,10)=LLV(TY,2*10+1); B2:=FILTER(A2,10); C2:=BACKSET(B2,10+1); LD:=FILTER(C2,10);
A:=REF(CLOSE,BARSLAST(HD)); B:=REF(CLOSE,BARSLAST(LD));
T1:=BARSLAST(HD)<BARSLAST(LD) AND NOT(HD) ;
T2:=BARSLAST(HD)>BARSLAST(LD) AND NOT(LD);
波峰:IF(T1,A,A),COLORFF00FF,POINTDOT;
STICKLINE(T1,A,A,1.5,0),COLORFF00FF;
波谷:IF(T2,B,B),COLOR80FF00,POINTDOT;
STICKLINE(T2,B,B,1.5,0),COLOR80FF00;
MA1:=MA(C,3);
XG1:=MA1>REF(MA1,1) AND REF(MA1,1)<REF(MA1,2) AND C>MA(C,7);
DRAWTEXT(FILTER(XG1,9),LOW*0.97,'B'),COLORRED,LINETHICK2;
DRAWICON(FILTER(XG1,9),LOW*0.98,1);
VAR2:=SUM(IF(CLOSE>OPEN,VOL,0),30)/SUM(VOL,30)*100;
VAR3:=100-SUM(IF(CLOSE>OPEN,VOL,0),30)/SUM(VOL,30)*100;
多頭力量:= VAR2;
空頭力量:= VAR3;
RSV:=(CLOSE-LLV(LOW,18))/(HHV(HIGH,18)-LLV(LOW,18))*100;
K:=SMA(RSV,3,1);
D:=SMA(K,3,1);
XG2:=多頭力量 > 空頭力量 AND 多頭力量 - 空頭力量>30 AND CROSS(D,K) OR
MA1<REF(MA1,1) AND REF(MA1,1)>REF(MA1,2) AND REF(MA1,2)>REF(MA1,3) AND K>50;
DRAWTEXT(FILTER(XG2,9),H*1.06,'S'),COLORGREEN,LINETHICK2;
DRAWICON(FILTER(XG2,9),H*1.02,2);
{跳空缺口}
LL1:=REF(L,1);
HH1:=REF(H,1);
SQK:=L>HH1;
XQK:=H<LL1;
上跳:IF(SQK=1,L-HH1,DRAWNULL),COLORFF00FF,CROSSDOT,LINETHICK3,NODRAW;
下跳:IF(XQK=1,H-LL1,DRAWNULL),COLORGREEN,CROSSDOT,LINETHICK3,NODRAW;
STICKLINE(SQK,L,HH1,4*1,1),COLORYELLOW;{上跳}
STICKLINE(XQK,H,LL1,4*1,2),COLOR00FF00;{下跳}
DRAWTEXT(SQK,H,'上跳'),COLORYELLOW;
DRAWTEXT(XQK,L,'下跳'),COLOR00FF00;
{補缺口}
K1:=BARSLAST(L>REF(H,1));
K2:=L<REF(H,K1+1) AND COUNT(L<REF(H,K1+1),K1)=1;
STICKLINE(K2,L,O,1,0),COLORFF00FF;{缺口回補};
DRAWTEXT(K2=1,L,'回補'),COLORFF00FF;

4. 通達信將選股公式改為幅圖或主圖指標

如何將主、副圖公式改為選股公式
以下是將主、副圖公式改為選股公式的簡易方法，求人不如求己。

步驟一.將所有的顯示式":",改為不顯示式":="
選股條件的基本要求為只能輸出1個條件式,故要先將公式中所有的顯示式":"改為不顯示式":=",
如果原來顯示式後面接有線型描述(顏色.對齊..等),也一並刪除
例如:
ma1:ma(c,5),colorred;
ma2:ma(c,10),colorgreen,POINTDOT;
.....

先改為
ma1:=ma(c,5);
ma2:=ma(c,10);
.....

步驟二.找出選股條件,並寫成選股式引用:
條件的尋找方法,依不同目的,大致可分以下幾種:
--------------------------------------------------------------------------------------------
1.'字'選股 如:'買'選股
方法:先找出公式中出現有'字'的地方,該式開頭會以DRAW..TEXT開頭,
DRAWTEXT DRAWTEXTEX DRAWYITEXT DRAWFLAGTEXT DRAWMOVETEXT
找到後,該函數(條件, ,'字')後面括弧內的第1個即為條件,將該條件復制出來並加上分號即可
例如:
{求'5日均>10日均'選股}
ma1:=ma(c,5);
ma2:=ma(c,10);
DRAWTEXT(ma1>ma2,ma1,'5日均>10日均');
[解]
ma1:=ma(c,5);
ma2:=ma(c,10);
ma1>ma2;
--------------------------------------------------------------------------
2.圖標選股 如:笑臉選股
方法:
先依不同軟體,找出該圖標的代號,
再找出公式中出現DRAWICON函數(條件, ,圖標代號)的式子,對照圖標的代號(括弧內的第3個),如果該圖標代號為所求代號,
該函數後面括弧內的第1個即為條件,將該條件復制出來並加上分號即可
例如:
{求圖標1選股}
ma1:=ma(c,5);
ma2:=ma(c,10);
DRAWicon(ma1>ma2,ma1,1);
[解]
ma1:=ma(c,5);
ma2:=ma(c,10);
ma1>ma2;
--------------------------------------------------------------------------------
3.A線上穿(下穿)B線選股 {上穿--金叉,下穿--死叉}
方法:A線上穿B線: cross(A,B);
A線下穿B線: cross(B,A);
例如:
{求ma1上穿ma2選股}
ma1:ma(c,5);
ma2:ma(c,10);
[解]
ma1:=ma(c,5);
ma2:=ma(c,10);
cross(ma1,ma2);

{求ma1下穿ma2選股}
ma1:ma(c,5);
ma2:ma(c,10);
[解]
ma1:=ma(c,5);
ma2:=ma(c,10);
cross(ma2,ma1);

-------------------------------------------------------------------------------------------
4.線A上穿(下穿) 選股
方法:線A上穿: cross(A,ma(A,2)); 或 cross(A,ref(A,1));
線A下穿: cross(ma(A,2),A); 或 cross(ref(A,1),A);
例如:
{求改成ma1上穿}
ma1:ma(c,5);
[解]
ma1:=ma(c,5);
cross(ma1,ma(ma1,2));
或
ma1:=ma(c,5);
cross(ma1,ref(ma1,1));

{求改成ma1下穿}
ma1:ma(c,5);
[解]
ma1:=ma(c,5);
cross(ma(ma1,2),ma1);
或
ma1:=ma(c,5);
cross(ref(ma1,1),ma1);
---------------------------------------------------------------------------------------------
5.第1次出現條件A 選股
方法:先找出條件A,
再利用cross(A,0.5);

例如:
{求改成出現圖標1選股}
ma1:=ma(c,5);
ma2:=ma(c,10);
DRAWicon(ma1>ma2,ma1,1);
[解1]
ma1:=ma(c,5);
ma2:=ma(c,10);
A:=ma1>ma2;
cross(A,0.5);
[解2--直接將條件A寫入]
ma1:=ma(c,5);
ma2:=ma(c,10);
cross(ma1>ma2,0.5);
-------------------------------------------------------------------------------------------
6.線變色選股 如:黃線變紅色選股 (指標線為黃線,再利用函數變紅色線)
方法:先依不同軟體,找出條件A,
再用cross(A,0.5);

(1)飛狐
條件在PARTLINE(條件A, ),colorred;括弧內的第1個即為條件,將該條件復制出來並加上分號即可
例如:
{求黃線變紅色選股 飛狐}
ma1:ma(c,5),coloryellow;
PARTLINE(ma1>REF(ma1,1),ma1),colorred;
[解]
ma1:=ma(c,5);
A:=ma1>REF(ma1,1);
cross(A,0.5);

(2)大智慧L2.分析家
條件在PARTLINE( ,條件A,rgb(255,0,0), , ...);
括弧內為rgb(255,0,0)的前1個即為條件,將該條件復制出來並加上分號即可
例如:
{求黃線變紅色選股 大智慧L2.分析家}
ma1:=ma(c,5);
PARTLINE(ma1,ma1>REF(ma1,1),rgb(255,0,0),1,rgb(255,255,0));
[解]
ma1:=ma(c,5);
A:=ma1>REF(ma1,1);
cross(A,0.5);

(3)通達信
條件在IF(條件A, ,DRAWNULL),colorred;括弧內的第1個即為條件,將該條件復制出來並加上分號即可
例如:
{求黃線變紅色選股 通達信}
MA1:MA(C,5),COLORYELLOW;
IF(MA1>REF(MA1,1),MA1,DRAWNULL),COLORRED;
[解]
MA1:=MA(C,5);
A:=MA1>REF(MA1,1);
CROSS(MA1>REF(MA1,1),0.5);
--------------------------------------------------------------------------------
7.顏色柱選股
方法:先找出公式中出現有STICKLINE函數的地方,
找到後,核對該函數後面的顏色,是否為所求顏色,
若顏色相同,則括弧內的第1個即為條件A,將該條件復制出來並加上分號即可

例如:
{求紅色柱選股}
STICKLINE(c>o,h,l,0.8,1),colorred;
[解]
A:c>o;

{求第1次紅色柱選股}
STICKLINE(c>o,h,l,0.8,1),colorred;
[解]
A:=c>o;
cross(A,0.5);

步驟三.最後將所有繪圖函數及單一輸出值(如 0; k; if(,,); )全刪除,使公式只剩1個選股式輸出即成,
(若有2個以上條件,條件同時成立時,可在條件間用"and"連接;
若有2個以上條件,允許條件不同時成立時,可在條件間用"or"連接)；

5. 通達信最牛最全主圖指標公式怎麼樣

沒有最牛的指標，只有最熊的指標

6. 請高手把這個通達信主圖公式改成選股指標

第一個

N:=IF(BARSCOUNT(C)>=48,48,BARSCOUNT(C));

AMOV:=VOL*(C+L+H)/3;

MN:=SUM(AMOV,N)/SUM(VOL,N);

XG1:C>MN;

第二個

N1:=IF(BARSCOUNT(C)>=8,8,BARSCOUNT(C));

MN1:=SUM(AMOV,N1)/SUM(VOL,N1);

XG2:C>=MN1 AND REF(C<MN1,1);

你說的收盤價由灰色變為黃色我沒看見,短線是由綠色變為黃色,中線是由灰色變為黃色,上面公式第一個是收盤價大於中線,第二個是短線由綠線變為黃色